home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - DOS Part 2 / DOS039.dsk / PRIME FACTORS OF INTEGERS.bas < prev    next >
BASIC Source File  |  2012-02-16  |  1KB  |  60 lines
  1. 10 ARG$ = "PRIME FACTORS OF INTEGERS": GOSUB 1000
  2. 12 ARG$ = "ADAM OSBORNE & ASSOCIATES": GOSUB 3000
  3. 20  PRINT 
  4. 25  GOSUB 2000
  5. 30  PRINT "(ENTER 0 TO END PROGRAM)"
  6. 35  PRINT 
  7. 40  PRINT  CHR$(7): REM   BELL
  8. 45  INPUT "ENTER NUMBER:";Z
  9. 59  REM  - END PROGRAM
  10. 60  IF Z = 0  THEN 200
  11. 69  REM  - THE SIGN OF THE NUMBER IS ALWAYS A FACTOR
  12. 70  PRINT  SGN(Z)
  13. 79  REM  - USE ABSOLUTE VALUE FOR CALCULATIONS
  14. 80 Z =  ABS(Z)
  15. 89  REM  - LOOP TO TEST ALL INTEGERS (2 THRU Z) AS PRIME FACTORS
  16. 90  FOR I = 2 TO Z
  17. 100 S = 0
  18. 110  IF (Z/I) < > INT(Z/I)  THEN 150
  19. 120 Z = Z/I
  20. 130 S = S +1
  21. 140  GOTO 110
  22. 149  REM  - FIND A PRIME FACTOR? IF YES, PRINT
  23. 150  IF S = 0  THEN 170
  24. 159  REM  - PRINT FACTORS WITH EXPONENTS; I^S = I TO THE S POWER
  25. 160  PRINT I;"^";S
  26. 170  NEXT I
  27. 180  PRINT 
  28. 189  REM  - RESTART PROGRAM
  29. 190  GOTO 40
  30. 200  END 
  31. 999  END 
  32. 1000  REM  SCREEN HEADING
  33. 1001  REM 
  34. 1010  HOME 
  35. 1020 BELL$ =  CHR$(7): REM  BELL SOUND
  36. 1040  PRINT BELL$
  37. 1050  HTAB ((40 - LEN(ARG$))/2)
  38. 1060  INVERSE 
  39. 1070  PRINT ARG$
  40. 1080  NORMAL 
  41. 1090  FOR X = 1 TO 38
  42. 1100  PRINT "-";
  43. 1110  NEXT 
  44. 1120  PRINT "-"
  45. 1990  RETURN 
  46. 1999  REM 
  47. 2000  REM  DISPLAY COMMENTARY
  48. 2001  REM 
  49. 2010  PRINT "THIS PROGRAM WILL TAKE ANY INTEGER AND  CALCULATE ITS PRIME FACTORS. "
  50. 2020  PRINT 
  51. 2990  RETURN 
  52. 3000  REM  SUBHEADING
  53. 3001  REM 
  54. 3050  HTAB ((40 - LEN(ARG$))/2)
  55. 3070  PRINT ARG$
  56. 3090  FOR X = 1 TO 38
  57. 3100  PRINT "-";
  58. 3110  NEXT 
  59. 3120  PRINT "-"
  60. 3130  RETURN